Youtube downloader

Понадобилось, вдруг, скачать несколько роликов с ютуба, оказалось нечем. Мой старый не работает, Злобинский тоже не работает, youtube-dl из убунтовского репозитория тоже не работает. Пришлось делать новый.

#!/usr/bin/perl --
#
# ytd.pl -- youtube downloader

use strict;
use warnings;
use LWP::UserAgent;
use URI::Escape;

die "Usage: ytd.pl VideoURL\n" unless @ARGV;

my $videourl = shift;
my $ua = LWP::UserAgent->new;
my $response = $ua->get($videourl);
my ($outflv) = $response->content =~ m{<meta name="title" content="([^"]+)">};

die "Can't find video title\n" unless $outflv;

while( -e "$outflv.flv" ) {
  $outflv = $outflv =~ /_(\d+)$/ ? "${`}_" . ($1+1) :  "${outflv}_1";
}

my $link = [ map { map {split '\|'} split ',', uri_unescape($_) } $response->content =~ m{fmt_url_map=([^&]+)} ]->[1];
die "Can't find video link\n" unless $link;

$| = 1;

print "Saving video to $outflv.flv...\n";

my ($received_size, $i) = (0, 0);
open my $fh, '>' , "$outflv.flv" or die $!;
binmode $fh;
$ua->get($link, ':content_cb' => sub { my ($data, $response) = @_;
                                       $received_size += length $data;
                                       print {$fh} $data;
                                       printf "\r" . [qw(- \\ | /)]->[++$i % 4] . ' %d%%         ',
                                         100 * $received_size / ($response->header('Content-Length') || 1);
                                     });
print "\nDone.\n";